13.1　サンプルプログラムの全体

// コールバック関数を使うための準備
#include "modclbk.as"
    newclbk3 cb_win_delete_event, 3, *on_win_delete_event, CLBKMODE_CDECL@
    newclbk3 cb_btn_toggled, 2, *on_btn_toggled, CLBKMODE_CDECL@

// GTK+の関数を使うための準備
#uselib "libgtk-3-0.dll"
#func global gtk_init "gtk_init" sptr, sptr
#func global gtk_window_new "gtk_window_new" int
#func global gtk_widget_show_all "gtk_widget_show_all" sptr
#func global gtk_main "gtk_main"
#func global gtk_main_quit "gtk_main_quit"
#func global gtk_container_set_border_width "gtk_container_set_border_width" sptr, int
#func global gtk_container_add "gtk_container_add" sptr, sptr
#func global gtk_vbox_new "gtk_vbox_new" int, int
#func global gtk_box_pack_start "gtk_box_pack_start" sptr, sptr, int, int, int
#func global gtk_toggle_button_new_with_label "gtk_toggle_button_new_with_label" sptr
#func global gtk_toggle_button_set_active "gtk_toggle_button_get_active" sptr, int
#func global gtk_toggle_button_get_active "gtk_toggle_button_get_active" sptr
#func global gtk_button_set_label "gtk_button_set_label" sptr, sptr
#func global gtk_spinner_new "gtk_spinner_new"
#func global gtk_spinner_start "gtk_spinner_start" sptr
#func global gtk_spinner_stop "gtk_spinner_stop" sptr

#uselib "libgobject-2.0-0.dll"
#define g_signal_connect(%1, %2, %3, %4) g_signal_connect_data %1, %2, %3, %4, 0, 0
#func global g_signal_connect_data "g_signal_connect_data" sptr, str, sptr, sptr, int, int

// よく使う定数
; ヌルポインタ
#const NULL 0
; 真偽値
#const FALSE 0
#const TRUE 1

    // GTK+初期化
    gtk_init NULL, NULL

    // ウィンドウ生成
#const GTK_WINDOW_TOPLEVEL 0 ; GtkWindowType
    gtk_window_new GTK_WINDOW_TOPLEVEL
    win = stat
    gtk_container_set_border_width win, 5
    g_signal_connect win, "delete-event", cb_win_delete_event, NULL

    // VBox生成
    gtk_vbox_new FALSE, 6
    vbox = stat

    // トグルボタン生成
    gtk_toggle_button_new_with_label "Start Spinning"
    btn = stat
    gtk_toggle_button_set_active btn, FALSE
    g_signal_connect btn, "toggled", cb_btn_toggled, NULL

    // スピナー生成
    gtk_spinner_new
    spn = stat

    // ウィンドウの組み立て
    gtk_box_pack_start vbox, btn, TRUE, TRUE, 0
    gtk_box_pack_start vbox, spn, TRUE, TRUE, 10
    gtk_container_add win, vbox

    // ウィンドウの表示とメインループの開始
    gtk_widget_show_all win
    gtk_main
    end

/* シグナルハンドラ */
*on_win_delete_event
    gtk_main_quit
    return

*on_btn_toggled
    gtk_toggle_button_get_active btn
    if stat {
        gtk_spinner_start spn
        gtk_button_set_label btn, "Stop Spinning"
    }
    else {
        gtk_spinner_stop spn
        gtk_button_set_label btn, "Start Spinning"
    }
    return

Prev - Table of contents - Next