// コールバック関数を使うための準備
#include "modclbk.as"
newclbk3 cb_win_delete_event, 3, *on_win_delete_event, CLBKMODE_CDECL@
newclbk3 cb_btn_clicked, 2, *on_btn_clicked, CLBKMODE_CDECL@
// GTK+の関数を使うための準備
#uselib "libgtk-3-0.dll"
#func global gtk_init "gtk_init" sptr, sptr
#func global gtk_window_new "gtk_window_new" int
#func global gtk_widget_show_all "gtk_widget_show_all" sptr
#func global gtk_main "gtk_main"
#func global gtk_main_quit "gtk_main_quit"
#func global gtk_button_new_with_label "gtk_button_new_with_label" sptr
#func global gtk_container_add "gtk_container_add" sptr, sptr
#uselib "libgobject-2.0-0.dll"
#define g_signal_connect(%1, %2, %3, %4) g_signal_connect_data %1, %2, %3, %4, 0, 0
#func global g_signal_connect_data "g_signal_connect_data" sptr, str, sptr, sptr, int, int
;#func global g_signal_handler_disconnect "g_signal_handler_disconnect" sptr, int
// ヌルポインタ定数
#const NULL 0
// GTK+初期化
gtk_init NULL, NULL
// ウィンドウ生成
#const GTK_WINDOW_TOPLEVEL 0 ; GtkWindowType
gtk_window_new GTK_WINDOW_TOPLEVEL
win = stat
g_signal_connect win, "delete-event", cb_win_delete_event, NULL
// ボタン生成
gtk_button_new_with_label "Click Here"
btn = stat
g_signal_connect btn, "clicked", cb_btn_clicked, NULL
; id = stat
; g_signal_handler_disconnect btn, id
// ウィンドウの組み立て
gtk_container_add win, btn
// ウィンドウの表示とメインループの開始
gtk_widget_show_all win
gtk_main
end
/* シグナルハンドラ */
*on_win_delete_event
gtk_main_quit
return
*on_btn_clicked
mes "Hello World"
return
以後、前節と同じように各パートの説明になりますが、前節と2章で既に説明した内容は省略します。